Millisecond Forums

You set up a <picture> element, define the image file(s) you want to display as its /items and then display the <picture> element via your <trial> elements' /stimulustimes or -frames

<picture somepicture>
/ items = ("someimagefile.jpg")
...
</picture>

<trial sometrial>
/ stimulusframes = [1=somepicture]
...
</trial>

This is very helpful, thank you!  I tried using these steps but the file I want to use still isn't being recognized by Inquisit. Do I have to do something differently to define the image file?

The file ought to be located in the same directory / folder as the script itself (e.g. both the script and the image file would reside on your Desktop). There's also a minimal chance that there's something wrong with the file (e.g. invalid metadata), preventing Inquisit from being able to use it. In that case, you can open the file in a simple graphics program (Microsoft Paint will do), and re-save it under a different name or format. Also make sure you don't have any typo in the /items attribute (i.e. the file name is given correctly) and that the image is of a supported format (e.g. JPG or PNG, Photoshop PSDs will not work for example). If none of this helps, attach the script and image file to this thread. Put them in a ZIP archive and click +Insert -> Add File to attach the ZIP to your response here.

Here is the file. As you'll see, all I need is a simple equation (1+1=?). My ultimate goal is to display equations like this on the screen, with the next screen asking what color the equation is in. I would do the same thing multiple times, the only difference being the colors. That's all I need for this whole project, but since this is my first time creating a script without instruction, I am having quite a bit of trouble. 

Okay, thanks for the additional details. The image displays fine (see attached example).

I am, however, wondering why you would want to use images for this:

"My ultimate goal is to display equations like this on the screen, with the next screen asking what color the equation is in. I would do the same thing multiple times, the only difference being the colors."

This should be much easier to do using standard <text> elements. Something like:

<defaults>
/ inputdevice = mouse
</defaults>

<block myblock>
/ trials = [1-8 = noreplace(black, green, blue, red)]
</block>

<trial black>
/ ontrialbegin = [text.equation.textcolor = black;]
/ stimulustimes = [1=equation; 1000=blank, question, black, green, blue, red]
/ validresponse = (black, green, blue, red)
/ correctresponse = (black)
</trial>

<trial green>
/ ontrialbegin = [text.equation.textcolor = green;]
/ stimulustimes = [1=equation; 1000=blank, question, black, green, blue, red]
/ validresponse = (black, green, blue, red)
/ correctresponse = (green)
</trial>

<trial blue>
/ ontrialbegin = [text.equation.textcolor = blue;]
/ stimulustimes = [1=equation; 1000=blank, question, black, green, blue, red]
/ validresponse = (black, green, blue, red)
/ correctresponse = (blue)
</trial>

<trial red>
/ ontrialbegin = [text.equation.textcolor = red;]
/ stimulustimes = [1=equation; 1000=blank, question, black, green, blue, red]
/ validresponse = (black, green, blue, red)
/ correctresponse = (red)
</trial>

<text equation>
/ items = equations
</text>

<item equations>
/ 1 = "1 + 1 = ?"
/ 2 = "2 + 2 = ?"
/ 3 = "3 + 3 = ?"
/ 4 = "4 + 4 = ?"
/ 5 = "5 + 5 = ?"
/ 6 = "6 + 6 = ?"
/ 7 = "7 + 7 = ?"
/ 8 = "8 + 8 = ?"
</item>

<shape blank>
/ shape = rectangle
/ color = white
/ size = (100%, 100%)
</shape>

<text question>
/ items = ("What color was the equation?")
</text>

<text black>
/ items = ("BLACK")
/ txcolor = black
/ position = (20%, 75%)
</text>

<text green>
/ items = ("GREEN")
/ txcolor = green
/ position = (40%, 75%)
</text>

<text blue>
/ items = ("BLUE")
/ txcolor = blue
/ position = (60%, 75%)
</text>

<text red>
/ items = ("RED")
/ txcolor = red
/ position = (80%, 75%)
</text>

This is much easier! Thank you SO much! I really appreciate it!!!!!

If I wanted to add an instructions page, how would I do that? All I want to say is "In this task you will be presented with arithmetic equations"

Set up a <page> element with your instructions

<page intro>
^In this task you will be presented with arithmetic equations.
</page>

and display it via the <block>'s /preinstructions:

<block myblock>
/ preinstructions = (intro)
/ trials = [1-8 = noreplace(black, green, blue, red)]
</block>

Thank you! I am also trying to use the same practice trials and instructions from the operation span task. Is there an easy way to copy this from the operation span template on inquisit?