Millisecond Forums

The description in that article is a bit low on details, but here's how to build something like this:

<text mathproblem>
/ items = problems
/ erase = false
</text>

<text mathanswer>
/ items = answers
/ select = text.mathproblem.currentindex
/ position = (50%, 55%)
/ erase = false
</text>

<item problems>
/ 1 = "1 + 2 + 3 + 4 = ?"
/ 2 = "5 + 6 + 7 + 8 = ?"
</item>

<item answers>
/ 1 = "Answer: 10"
/ 1 = "Answer: 26"
</item>

<block mathblock>
/ trials = [1-2=showmathproblem]
</block>

<trial showmathproblem>
/ ontrialbegin = [
    values.spacebarcount = 0;
]
/ stimulustimes = [0=clearscreen, mathproblem; 10000=mathanswer]
/ validresponse = (57)
/ isvalidresponse = [
    if (trial.showmathproblem.response == 57){
        values.spacebarcount +=1;
    }; false;
]
/ timeout = 15000
/ beginresponsetime = 0
/ branch = [
    openended.entermathanswer
]
</trial>

<openended entermathanswer>
/ position = (50%, 60%)
</openended>

<values>
/ spacebarcount = 0
</values>

<data>
/ columns = [
    date time subject group blocknum blockcode trialnum trialcode stimulusitem response latency correct
    values.spacebarcount
]
/ separatefiles = true
</data>

What it does:
(1) Display a math problem.
(2) After 10 seconds the "glitch" occurs, i.e. the answer is displayed.

During (1) and (2) the number of space bar presses is continuously counted. The number is logged in values.spacebarcount.

(3) 5 seconds later, a prompt appears where participants are supposed to enter "their" answer.

Hope this helps.

That...is amazing! 

Now, I'm sorry for doing the "Give them a finger, and they'll take the whole hand" cliche:

how would I make it so the answers would display only after the participant presses the spacebar?

Essentialy that would change the scenario to this:

"Please don't press the spacebar as there's a glitch that will display the answer when it's pressed! 
(1) Display a math problem.
The participant can then provide an answer to continue to the next problem (any, doesn't have to be correct) OR press the spacebar (once) to initiate the "glitch".
Spacebar presses are then recorded for each problem seperately (so pressing the spacebar 10x times during problem would still count as "1", 5x times during problem #2 counts as "2" and so on)
 
Is...is this as complicated as it seems or do you just have to get used to it?

This shouldn't be particularly complicated. You could do something like this:

<text mathproblem>
/ items = problems
/ erase = false
</text>

<text mathanswer>
/ items = answers
/ select = text.mathproblem.currentindex
/ position = (50%, 55%)
/ erase = false
</text>

<item problems>
/ 1 = "1 + 2 + 3 + 4 = ?"
/ 2 = "5 + 6 + 7 + 8 = ?"
</item>

<item answers>
/ 1 = "Answer: 10"
/ 1 = "Answer: 26"
</item>

<block mathblock>
/ trials = [1-2=showmathproblem]
</block>

<trial showmathproblem>
/ ontrialend = [
    if(trial.showmathproblem.response == 57) values.spacebarcount += 1;
]
/ stimulustimes = [0=clearscreen, mathproblem]
/ validresponse = (anyresponse)
/ responsemessage = (57, mathanswer, 2000)
/ branch = [
    openended.entermathanswer
]
</trial>

<openended entermathanswer>
/ position = (50%, 60%)
</openended>

<values>
/ spacebarcount = 0
</values>

<data>
/ columns = [
    date time subject group blocknum blockcode trialnum trialcode stimulusitem response latency correct
    values.spacebarcount
]
/ separatefiles = true
</data>