Millisecond Forums

That's certainly sounds possible to do, but your description is too terse to give you a concrete example. Can you describe how -- exactly -- you want the trials to look and behave. Give an example for say, 4 visual and auditory stimuli with all details (i.e. the dynamic criteria and response options).

Thanks for the super fast response. Let's see...something as follows (but I have not finalized the exact number of stimuli yet)

1. Subject is presented with an image stimulus
2. Subject is presented with an auditory stimulus
3. Subject is presented with two (or more>?) options on the screen (either words or images) from which he/she must select the 'correct' option

A concrete example of one run through this might be:

1. Image of a dog is presented for a predetermined amount of time (500ms for example)
2. The word "dog" is played via a .wav file
3. An image of a dog and a cat appear on the screen (left and right) and the subject is required to select the dog OR the words "cat" and "dog" appear and the subject is expected to select "dog".

This process (1, 2, 3) is repeated for a predetermined number of stimuli...say ten for now. Each one will be different so the option which subjects select from in #3 will be unique each time. All of the predesigned scripts I've managed to download and fiddle with thus far use binary categorization schemes (pleasant / unpleaseant, good / bad, etc) for subject response options. I'm trying to figure out how to extend the script for the scenario I desire and understand, I think, that there will need to be unique portions in the script for each run through the 1, 2, 3, sequence but, as I haven't gotten my head around the scripting yet, I'm a bit lost.

Regards

Jason

This is fairly straightforward to set up if you're going for clickable / touchable response options. You always have two response options the correct response (dog in your single concrete example) and a distractor option (cat in your example). Here's an example with four stimuli, scaling this up to 10 or however many you need is trivial, you simply add the items and increase the number of trials accordingly.

<picture mypicture>
/ items = pictureitems
</picture>

<item pictureitems>
/ 1 = "dog.jpg"
/ 2 = "apple.jpg"
/ 3 = "girl.jpg"
/ 4 = "fire.jpg"
</item>

<sound mysound>
/ items = sounditems
/ select = picture.mypicture.currentindex
</sound>

<item sounditems>
/ 1 = "dog.wav"
/ 2 = "apple.wav"
/ 3 = "girl.wav"
/ 4 = "fire.wav"
</item>

<text correctoption>
/ items = correctitems
/ select = picture.mypicture.currentindex
/ vposition = 90%
/ hposition = list.hpos.nextvalue
</text>

<item correctitems>
/ 1 = "Dog"
/ 2 = "Apple"
/ 3 = "Girl"
/ 4 = "Fire"
</item>

<text distractoroption>
/ items = distractoritems
/ select = picture.mypicture.currentindex
/ vposition = 90%
/ hposition = list.hpos.nextvalue
</text>

<item distractoritems>
/ 1 = "Cat"
/ 2 = "Orange"
/ 3 = "Boy"
/ 4 = "Water"
</item>

// randomize the left-right position of the two response options
<list hpos>
/ items = (20%, 80%)
/ selectionrate = always
</list>

<trial mytrial>
/ stimulustimes = [0=mypicture; 500=clearscreen, mysound; 2000=clearscreen, correctoption, distractoroption]
/ inputdevice = mouse
/ validresponse = (correctoption, distractoroption)
/ correctresponse = (correctoption)
</trial>

<block myblock>
/ trials = [1-4 = mytrial]
</block>

Awesome! Thanks, that is more than a 'kick in the right direction'. :-) You helped to get me jump started. 
Regards
Jason