Millisecond Forums

Re. #1: If you want to force participants to write something for a minimum amount of time before allowing them to move on, you can do so per /isvalidresponse. E.g.
https://www.millisecond.com/forums/FindPost10291.aspx

Re. #2: You need several <batch> conditions -- one per possible order -- and assign your participants to one of those conditions randomly:

<batch>
/ subjects = (1 of 4)
/ groupassignment = random
/ file = "a.iqx"
/ file = "fullfree2.iqx"
/ file = "b.iqx"
/ file = "c.iqx"
</batch>

<batch>
/ subjects = (2 of 4)
/ groupassignment = random
/ file = "a.iqx"
/ file = "fullfree9.iqx"
/ file = "b.iqx"
/ file = "c.iqx"
</batch>

<batch>
/ subjects = (3 of 4)
/ groupassignment = random
/ file = "a.iqx"
/ file = "fullsuppress2.iqx"
/ file = "b.iqx"
/ file = "c.iqx"
</batch>

<batch>
/ subjects = (4 of 4)
/ groupassignment = random
/ file = "a.iqx"
/ file = "fullsuppress9.iqx"
/ file = "b.iqx"
/ file = "c.iqx"
</batch>

Re. #3: It's not possible to suppress back navigation for instruction pages that form a *set*. What you need to do is present at least one of the instruction pages via a separate <block>. I.e.

<block EmotionalStroopInstr>
/preinstructions =(fullfree9)
</block>

<block EmotionalStroop>
/preinstructions =(sumfree9)
/ trials = [1 = getready; 2-73 =noreplace(targetword, NeutralWord, oppositeword)]
</block>

Then run the two blocks in sequence per your <expt>'s /blocks attribute.

<expt>
...
/ blocks = [...; 2 = sequence(EmotionalStroopInstr, EmotionalStroop); ...]
...
</expt>

Hi Dave, 

Thank you for your help about these.
I have a couple of follow-up questions with my current script.

I was able to set up a page with an open-ended response question. But something is not working and it won’t let me proceed to the next page though I 1) fulfilled the required wait time and 2) wrote something on the response box (currently I set up the required wait time to 10s).

1. Could you take a look at it and see what needs to be fixed? (I am pasting relevant section below…)

<htmlpage suppressioncondition>
/ file = "suppressioncondition.htm"
</htmlpage>

<text instruction>
/ items = ("In sum your tasks in writing this free response are the following:
1. SUPPRESS thinking about the saddest or most depressing event. DO NOT think about the event.
2. But if you catch yourself feeling sad or thinking about the event, type * (asterisk) whenever it occurs.")
/ fontstyle = ("Arial", 1.57%, true, false, false, false, 5, 0)
/ position = (50, 15)
/ txcolor = black
/ select = sequence
/ hjustify = left
/ size = (900,150)
</text>


<openended writesuppress>
/ stimulusframes = [1=instruction]
/ isvalidresponse = [openended.writesuppress.latency>=10000]
/ position = (50, 90)
/ linelength = 80
/ charlimit = 1000000
/ showmousecursor = true
/ inputdevice = keyboard
/ multiline = true
/ required = true
/ recorddata = true
/ size = (900, 500)
</openended>

<block supcondition>
/ preinstructions = (suppressioncondition)
/trials =[1 = writesuppress]
</block>



(So I created an iqx, combining open-ended question + Stroop Task + two mood rating scales using Emotional Stroop as the basis)

<expt>
/ blocks = [
     1 = supcondition;
       2 = StartInfo;
       3 = Practice_EmotionalStroop;
         4 = EmotionalStroop;
            5 = panasfinal;
           6 = vamsfinal;]
/ postinstructions = (end)
/onexptend = [
           values.completed = 1;
]
</expt>


Within this open-ended response question (where I ask them to write freely)--I am asking participants to type *(asterisk) whenever they are reminded of a sad/depressing event while they are completing the task. I have two questions with this.

A. Can whatever they write be recorded into the data? How do I specify that in <data> and <summarydata> sections?


The following is my current data and summary data section:

<data>
/separatefiles = true
/ columns = (build, computer.platform, date time subject blocknum blockcode trialnum trialcode values.target values.color 
                                    response correct latency)
</data>

********************
summary data
********************

<summarydata>
/columns = (script.startdate script.starttime script.subjectid script.groupid script.elapsedtime computer.platform values.completed
                                    expressions.meanrt_neu expressions.meanrt_dep expressions.meanrt_pos
                         expressions.bias_dep expressions.bias_pos,
                         expressions.perccorrect_neu, expressions.perccorrect_dep, expressions.perccorrect_pos,expressions.q1_panas_P, expressions.q2_panas_N, expressions.q3_panas_P, expressions.q4_panas_N, expressions.q5_panas_P, expressions.q6_panas_N, expressions.q7_panas_N,
expressions.q8_panas_N, expressions.q9_panas_P, expressions.q10_panas_P, expressions.q11_panas_N, expressions.q12_panas_P, expressions.q13_panas_N, expressions.q14_panas_P,
expressions.q15_panas_N, expressions.q16_panas_P, expressions.q17_panas_P, expressions.q18_panas_N, expressions.q19_panas_P, expressions.q20_panas_N, expressions.PA, expressions.NA, expressions.whattheywrote, expressions.vamsf1, expressions.vamsf2, expressions.vamsf3, expressions.vamsf4, expressions.vamsf5, expressions.vamsf6,
expressions.vamsf7, expressions.vamsf8, expressions.vamsf9, expressions.vamsf10, expressions.vamsf11, expressions.vamsf12,
expressions.vamsf13, expressions.vamsf14, expressions.vamsf15, expressions.vamsf16, expressions.vamsf17, expressions.vamsf18, expressions.vamsf19
expressions.vamsf20, expressions.vamsf21, expressions.vamsf22, expressions.vamsf23, expressions.vamsf24, expressions.vamsf25, expressions.vamsf26, expressions.vamsf27)
                                   
/ separatefiles = true
</summarydata>

 


B. Is there a way to write up an expression so that inquisit will automatically count the number of * a participant write in his/her writing?

The following is my current expressions section:

<expressions>
/percCorrect_dep = (values.correct_depressionwords/trial.depression.trialcount) * 100
/percCorrect_Neu = (values.correct_neutralwords/trial.neutralword.trialcount) * 100
/percCorrect_Pos = (values.correct_positivewords/trial.positiveword.trialcount) * 100

/meanRT_dep = values.sumrt_dep/values.correct_depressionwords
/meanRT_Neu = values.sumrt_neu/values.correct_neutralwords
/meanRT_Pos = values.sumrt_pos/values.correct_positivewords

/Bias_dep = expressions.meanrt_dep - expressions.meanrt_neu
/Bias_Pos = expressions.meanrt_pos - expressions.meanrt_neu

/PA = radiobuttons.q1_panas_P.response + radiobuttons.q3_panas_P.response + radiobuttons.q5_panas_P.response +
radiobuttons.q9_panas_P.response + radiobuttons.q10_panas_P.response + radiobuttons.q12_panas_P.response + radiobuttons.q14_panas_P.response +
radiobuttons.q16_panas_P.response + radiobuttons.q17_panas_P.response + radiobuttons.q19_panas_P.response
/NA = radiobuttons.q2_panas_N.response + radiobuttons.q4_panas_N.response + radiobuttons.q6_panas_N.response + radiobuttons.q7_panas_N.response +
radiobuttons.q8_panas_N.response + radiobuttons.q11_panas_N.response + radiobuttons.q13_panas_N.response + radiobuttons.q15_panas_N.response +
radiobuttons.q18_panas_N.response + radiobuttons.q20_panas_N.response

/whattheywrote = openended.writesuppress

</expressions>

 

Please let me know about this!
Greatly appreciate your help in advance!

Re. #1: You've set the <openended> to /inputdevice = keyboard

<openended writesuppress>
/ stimulusframes = [1=instruction]
/ isvalidresponse = [openended.writesuppress.latency>=10000]
/ position = (50, 90)
/ linelength = 80
/ charlimit = 1000000
/ showmousecursor = true
/ inputdevice = keyboard
/ multiline = true
/ required = true
/ recorddata = true
/ size = (900, 500)
</openended>

That means to submit the response you need to press CTRL+ENTER. If you want the "Continue" button to be clickable via the mouse instead, you need to set /inputdevice = mouse.

Re. #2:

In the raw trial by trial <data> file, the openended's response will be captured in the response column.
To capture that <openended>'s response in <summarydata>, log the openended's response property: openended.writesuppress.response

Re. #3:

To count the number of *s in the response, you can make use of string functions. Take the length of the response and subtract from it the length of the response _after_ you've replaced all asterisks with nothing:

<expressions>
/ count_asterisks = length(openended.writesuppress.response) - length(replaceall(openended.writesuppress.response, "*", ""))
...
</expressions>

Like so:

<text instruction>
/ items = ("In sum your tasks in writing this free response are the following:
1. SUPPRESS thinking about the saddest or most depressing event. DO NOT think about the event.
2. But if you catch yourself feeling sad or thinking about the event, type * (asterisk) whenever it occurs.")
/ fontstyle = ("Arial", 1.57%, true, false, false, false, 5, 0)
/ position = (50, 15)
/ txcolor = black
/ select = sequence
/ hjustify = left
/ size = (900,150)
</text>


<openended writesuppress>
/ stimulusframes = [1=instruction]
/ isvalidresponse = [openended.writesuppress.latency>=10000]
/ position = (50, 90)
/ linelength = 80
/ charlimit = 1000000
/ showmousecursor = true
/ inputdevice = mouse
/ multiline = true
/ required = true
/ recorddata = true
/ size = (900, 500)
</openended>

<block supcondition>
/trials =[1 = writesuppress; 2=asterisks]
</block>

<expressions>
/ count_asterisks = length(openended.writesuppress.response) - length(replaceall(openended.writesuppress.response, "*", ""))
</expressions>

<trial asterisks>
/ stimulusframes = [1=count]
/ validresponse = (57)
</trial>

<text count>
/ items = ("There were <%expressions.count_asterisks%> asterisks in your response.")
</text>

You can log that expression to the data file(s) just like the others.