Millisecond Forums

Thank you so much, this worked!!

What you are doing is you're sampling your AAT_1, AAT_2, AAT_3 and AAT_4 trials in equal proportions:

<block trained_AAT>
/ trials = [1 = instructions2; 2-81, 83-162, 164-243 = noreplace(AAT_1, AAT_2, AAT_3, AAT_4); 82, 163 = instructions3]
</block>

With 240 trials total, you'll get 60 trials of each.

I'm guessing here, but you probably want something like this:

noreplace(AAT_1,
AAT_2, AAT_2, AAT_2, AAT_2, AAT_2, AAT_2, AAT_2, AAT_2, AAT_2,
AAT_3, AAT_3, AAT_3, AAT_3, AAT_3, AAT_3, AAT_3, AAT_3, AAT_3,
AAT_4)

i.e. a 1:9:9:1 ratio.

Maybe you could explain how you have determined that you're not seeing the right proportions and what the proportions actually are.

From your description I neither understand what proportions you actually want, nor what the proportions actually are.

Hello,
The script I posted about a few months ago in this thread is working perfectly, thanks to your help. I am now working on another modified AAT script, which I have not been able to figure out how to modify properly. In the previous script, I needed each image shown an equal number of times. In the current script, I need the images shown in different proportions, and in the data file, I can see they are not in the proportions that I am trying to specify. I think the problem is the way I have written out the blocks but I would appreciate any assistance with where I have gone wrong here.

The breakdown of the 240 trials:
- 12 Threat pictures, shown 10 times each so a total of 120 trials. 9 of these times are Portrait/Pull (108 trials), 1 time each is Landscape/Push (12 trials).
- 12 Neutral pictures, shown 10 times each for another total of 120 trials. 1 time each Portrait/Pull, 9 times Landscape/Push.

There are 4 categories of images:
Category 1: 12 Threat Pictures, landscape orientation: indices 1-12 (I only list this in the list below 1 time)
Category 2: 12 Threat Pictures, portrait orientation: indices 13-24 (I list these 9 times below so it will show 9 times)
Category 3: 12 Neutral Pictures, landscape: indices 25-36 (I list these 9 times below so it will show 9 times)
Category 4: 12 Neutral Pictures, portrait: indices 37-48 (I only list this in the list below 1 time)

<list category1>
/ items = (1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12)
/ replace = false
</list>

<list category2>
/ items = (13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24,
13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24)
/ replace = false
</list>

<list category3>
/ items = (25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36,
25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36)
/ replace = false
</list>

<list category4>
/ items = (37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48)
/ replace = false
</list>

Then I have each of the 4 categories in AAT_1, AAT_2, AAT_3, and AAT_4

<trial AAT_1>
/ ontrialbegin = [
values.selectstimulus = list.category1.nextvalue;
values.targetcategory = 1;
values.targetformat = "l";
picture.targetstimulus.height = values.startheight_A;
values.starttime = script.elapsedtime;
values.endtime = 0;
values.completeRT = 0;
values.changedirection = 0;
values.finalresponse="";
]
/ stimulusframes = [1 = targetstimulus]
/ validresponse = (back, forward)
/ iscorrectresponse = [(values.expcondition == 1 && trial.AAT_1.response == "forward") || (values.expcondition == 2 && trial.AAT_1.response == "back")]
/ errormessage = true(error,0)
/ response = correct
/ monkeyresponse = [if (values.expcondition == 1) "forward" else "back"]
/ ontrialend = [
values.joystick_y = joystick.y;
values.joystick_change = abs(values.joystick_y);
values.trialcode = "AAT_1";
values.RT = trial.AAT_1.latency;
values.correct = trial.AAT_1.correct;
values.stimulus = picture.targetstimulus.currentitem;
if (trial.AAT_1.response == "forward")
values.initialresponse = "PUSH"
else
values.initialresponse = "PULL";
list.accuracy_overall.insertitem(trial.AAT_1.correct,1);
if (trial.AAT_1.correct) {
list.AAT1correctlatencies.insertitem(trial.AAT_1.latency, 1);
list.latencies_overall.insertitem(trial.AAT_1.latency, 1);
}
]
/ branch = [
if (trial.AAT_1.response == "forward")
trial.decrease
else
trial.increase;
]
/ recorddata = false
</trial>

<trial AAT_2>
/ ontrialbegin = [
values.selectstimulus = list.category2.nextvalue;
values.targetcategory = 1;
values.targetformat = "p";
picture.targetstimulus.height = values.startheight_B;
values.starttime = script.elapsedtime;
values.endtime = 0;
values.completeRT = 0;
values.changedirection = 0;
values.finalresponse="";
]
/ stimulusframes = [1 = targetstimulus]
/ validresponse = (back, forward)
/ iscorrectresponse = [(values.expcondition == 1 && trial.AAT_2.response == "back") || (values.expcondition == 2 && trial.AAT_2.response == "forward")]
/ errormessage = true(error,0)
/ response = correct
/ monkeyresponse = [if (values.expcondition == 1) "back" else "forward"]
/ ontrialend = [
values.joystick_y = joystick.y;
values.joystick_change = abs(values.joystick_y);
values.trialcode = "AAT_2";
values.RT = trial.AAT_2.latency;
values.correct = trial.AAT_2.correct;
values.stimulus = picture.targetstimulus.currentitem;
if (trial.AAT_2.response == "forward")
values.initialresponse = "PUSH"
else
values.initialresponse = "PULL";
list.accuracy_overall.insertitem(trial.AAT_2.correct,1);
if (trial.AAT_2.correct) {
list.AAT2correctlatencies.insertitem(trial.AAT_2.latency, 1);
list.latencies_overall.insertitem(trial.AAT_2.latency, 1);
}
]
/ branch = [
if (trial.AAT_2.response == "forward")
trial.decrease
else
trial.increase
]
/ recorddata = false
</trial>

<trial AAT_3>
/ ontrialbegin = [
values.selectstimulus = list.category3.nextvalue;
values.targetcategory = 2;
values.targetformat = "l";
picture.targetstimulus.height = values.startheight_A;
values.starttime = script.elapsedtime;
values.endtime = 0;
values.completeRT = 0;
values.changedirection = 0;
values.finalresponse="";
]
/ stimulusframes = [1 = targetstimulus]
/ validresponse = (back, forward)
/ iscorrectresponse = [(values.expcondition == 1 && trial.AAT_3.response == "forward") || (values.expcondition == 2 && trial.AAT_3.response == "back")]
/ errormessage = true(error,0)
/ response = correct
/ monkeyresponse = [if (values.expcondition == 1) "forward" else "back"]
/ ontrialend = [
values.joystick_y = joystick.y;
values.joystick_change = abs(values.joystick_y);
values.trialcode = "AAT_3";
values.RT = trial.AAT_3.latency;
values.correct = trial.AAT_3.correct;
values.stimulus = picture.targetstimulus.currentitem;
if (trial.AAT_3.response == "forward")
values.initialresponse = "PUSH"
else
values.initialresponse = "PULL";
list.accuracy_overall.insertitem(trial.AAT_3.correct,1);
if (trial.AAT_3.correct) {
list.AAT3correctlatencies.insertitem(trial.AAT_3.latency, 1);
list.latencies_overall.insertitem(trial.AAT_3.latency, 1);
}
]
/ branch = [
if (trial.AAT_3.response == "forward")
trial.decrease
else
trial.increase;
]
/ recorddata = false
</trial>

<trial AAT_4>
/ ontrialbegin = [
values.selectstimulus = list.category4.nextvalue;
values.targetcategory = 2;
values.targetformat = "p";
picture.targetstimulus.height = values.startheight_B;
values.starttime = script.elapsedtime;
values.endtime = 0;
values.completeRT = 0;
values.changedirection = 0;
values.finalresponse="";
]
/ stimulusframes = [1 = targetstimulus]
/ validresponse = (back, forward)
/ iscorrectresponse = [(values.expcondition == 1 && trial.AAT_4.response == "back") || (values.expcondition == 2 && trial.AAT_4.response == "forward")]
/ errormessage = true(error,0)
/ response = correct
/ monkeyresponse = [if (values.expcondition == 1) "back" else "forward"]
/ ontrialend = [
values.joystick_y = joystick.y;
values.joystick_change = abs(values.joystick_y);
values.trialcode = "AAT_4";
values.RT = trial.AAT_4.latency;
values.correct = trial.AAT_4.correct;
values.stimulus = picture.targetstimulus.currentitem;
if (trial.AAT_4.response == "forward")
values.initialresponse = "PUSH"
else
values.initialresponse = "PULL";
list.accuracy_overall.insertitem(trial.AAT_4.correct,1);
if (trial.AAT_4.correct) {
list.AAT4correctlatencies.insertitem(trial.AAT_4.latency, 1);
list.latencies_overall.insertitem(trial.AAT_4.latency, 1);
}
]
/ branch = [
if (trial.AAT_4.response == "forward")
trial.decrease
else
trial.increase
]
/ recorddata = false
</trial>

And then finally, the blocks, which I believe I have done incorrectly:

block practice_AAT>
/ trials = [1-2 = instructions; 3-12 = noreplace(practicetrial_A, practicetrial_B, practicetrial_C, practicetrial_D)]
</block>

<block trained_AAT>
/ trials = [1 = instructions2; 2-81, 83-162, 164-243 = noreplace(AAT_1, AAT_2, AAT_3, AAT_4); 82, 163 = instructions3]
</block>

<expt>
/ subjects = (1 of 1)
/ groupassignment = groupnumber
/ onexptbegin = [
values.expcondition = 1;
values.format1 = "PORTRAIT";
values.format2 = "LANDSCAPE";
values.startheight_A = parameters.Startheight_ratioA*values.Maxheight_px;
values.startheight_B = parameters.Startheight_ratioB* values.Maxheight_px;
]
/ blocks = [
1 = practice_AAT;
  2 = trained_AAT;
]
/ postinstructions = (End)
/ onexptend = [values.completed = 1]
</expt>

Thank you very much for any help!

Thank you very much!! This does indeed clarify what is going on and the options I have, I really appreciate the detail and examples.

There is a variable called values.stimulus in the AAT script. Variables store information -- you set them to some state and then they remain in that state until you explicitly change that state. In the AAT script, during each AAT trial values.stimulus is set to the item presented during the respective AAT trial. For example:

<trial AAT_1>
...
/ ontrialend = [
if (trial.AAT_1.responsey < values.mouse_y)
values.response = 1
else
values.response = 2;
values.mouse_change = abs(values.mouse_y - trial.AAT_1.responsey);
values.mouse_y = trial.AAT_1.responsey;
values.RT = trial.AAT_1.latency;
values.correct = trial.AAT_1.correct;
values.stimulus = picture.targetstimulus.currentitem;
if (values.response == 1)
values.initialresponse = "PUSH"
else
values.initialresponse = "PULL";
list.accuracy_overall.insertitem(trial.AAT_1.correct,1);
if (trial.AAT_1.correct) {
list.AAT1correctlatencies.insertitem(trial.AAT_1.latency, 1);
list.latencies_overall.insertitem(trial.AAT_1.latency, 1);
}
]
/ branch = [
if (values.response == 1)
trial.decrease
else
trial.increase;
]
/ recorddata = false
</trial>

If you then run some trial after a given AAT trial sequence that does not change the variable's state -- here: your instructions / break trial -- then the variable as logged in the data file will still accurately reflect the variable's current state. i.e. the target stimulus item displayed during the previous AAT trial. There is nothing wrong with that, it's how things *should* behave, it would be terrible if some trial that has no business manipulating a variable would change the variable's state without you having programmed the trial to do so. Ofterntimes you *want* a variable to maintain its state across several trials, for example if you are keeping track of points a participant has earned or a score s/he has achieved.

Here's a condensed example of what happens:

<values>
/ stimulus = ""
</values>

<block exampleblock>
/ trials = [1-4, 6-9 = stimulustrial; 5 = breaktrial]
</block>

// presents a stimulus
// stores the presented stimulus in a variable
<trial stimulustrial>
/ ontrialend = [
values.stimulus = text.mystimulus.currentitem;
]
/ stimulusframes = [1=mystimulus]
/ validresponse = (57)
</trial>

// a break after 4 trials
// displays no experimental stimulus
// and makes no changes to the variable
<trial breaktrial>
/ stimulusframes = [1=break]
/ validresponse = (57)
/ timeout = 5000
</trial>

<text mystimulus>
/ items = mystimulusitems
</text>

<item mystimulusitems>
/ 1 = "A"
/ 2 = "B"
/ 3 = "C"
/ 4 = "D"
/ 5 = "E"
/ 6 = "F"
/ 7 = "G"
/ 8 = "H"
</item>

<text break>
/ items = ("Take a short break.")
</text>

<data>
/ columns = (date time subject group blocknum blockcode trialnum trialcode values.stimulus response latency correct)
/ separatefiles = true
</data>

See for yourself in the data:



Now, what can you do if you want to prevent this? Several options:
(1) Filter out the break / instructions trial during analysis.
(2)  If you don't need any record of the instructions trial at all and it would not generate any data (e.g. viewing or break time) you *might* want to ever analyze or look at, you can force it to not be recorded by setting /recorddata = false:

// a break after 4 trials
// displays no experimental stimulus
// and makes no changes to the variable
<trial breaktrial>
/ stimulusframes = [1=break]
/ validresponse = (57)
/ timeout = 5000
/ recorddata = false
</trial>

The data then will look like this (note the gap in the trialnum column where the break trial would have been recorded):



(3) If you do not need to maintain the variables state (as is the case here, contrary to when keeping track of some cumulative score or points), you can have the instructions / break trial reset the varibale to nothing / an empty string:

// a break after 4 trials
// displays no experimental stimulus
// and resets the variable to nothing
<trial breaktrial>
/ ontrialend = [
values.stimulus = "";
]
/ stimulusframes = [1=break]
/ validresponse = (57)
/ timeout = 5000
</trial>

The data then would look like this:



This should hopefully clarify what's going on and what the options, including their advantages and disadvanteages, are.

Thank you Dave, my interpretation when I saw this output since I wasn't manually counting images during my practice run of all 480 trials, was that these photos had been shown for example 7 times instead of 6 times, since they were listed 7 times instead of 6 in the output. But my interpretation of your response is that the output is simply reflecting a prior photo that was shown during a trial? Would there be a way to program it so that this does not show in the output? If not then we will just ignore it in the future. Thank you!

> The photos shown in the Approach/Avoidance script are sometimes repeated 1 or 2 extra times, and I noticed in the output that when these photos are shown an extra time, they are running under the "trialcode" of "instructions2" rather than "InterTrialInterval" as the other photos are

Why should this mean that the images are shown an extra time? It does not mean that. It simply means that the variable that reflects which image was shown during the previous AAT trial still reflects that during the instructions2 trial where nothing changes -- the instructions trial does not select any new image, nor should it. That's exactly how things are supposed to work.

Hi Dave,
Thank you again for your invaluable help last month. We are currently double checking the output from our script to make sure it is running correctly and I noticed an error I am not sure how to solve. The photos shown in the Approach/Avoidance script are sometimes repeated 1 or 2 extra times, and I noticed in the output that when these photos are shown an extra time, they are running under the "trialcode" of "instructions2" rather than "InterTrialInterval" as the other photos are. I am thinking this is because of how I coded the breaks every 96 photos participants are shown - I am just not sure where I went wrong here. Thank you in advance for any help.

Here is how it is coded, please let me know if it would be helpful to attach the output as well.

Code for "instructions2" :
<text instructions2>
/ items = instructions2
/ select = sequence
/ position = (50%, 50%)
/ fontstyle = ("Arial", 3%, false, false, false, false, 5, 0)
/ txcolor = black
/ resetinterval = 3
/ size = (80%, 80%)
</text>

<item instructions2>
/ 1 = "PLEASE TAKE A FEW MOMENTS TO TAKE A BREAK DURING THE SESSION.
^^
Press press any key on the keyboard when you are ready to continue."
</item>

<trial instructions2>
/ stimulusframes = [1 = instructions2]
/ validresponse = ("anyresponse")
</trial>

Blocks:

<block practice_AAT>
/ trials = [1-2 = instructions; 3-12 = noreplace(practicetrial_A, practicetrial_B)]
</block>

<block assessment1untrained_AAT>
/ trials = [1-96, 98-193 = noreplace(AAT_1, AAT_2, AAT_3, AAT_4); 97, 194 = instructions2]
</block>

<block assessment2trained_AAT>
/ trials = [1-96, 98-193, 195-290 = noreplace(AAT_5, AAT_6, AAT_7, AAT_8); 97, 194 = instructions2]
</block>

Also if helpful the way the photos are categorized:
main category 1 (threat, untrained) landscape (1): indices 1-8
main category 1 (threat, untrained) portrait (2): indices 9-16
main category 2 (neutral, untrained) landscape (3): indices 17-24
main category 2 (neutral, untrained) portrait (4): indices 25-32

main category 3 (threat, trained) landscape (5): indices 33-44
main category 3 (threat, trained) portrait (6): indices 45-56
main category 4 (neutral, trained) landscape (7): indices 57-68
main category 4 (neutral, trained) portrait (8): indices 69-80

**8 threat Pictures, untrained, landscape**
<list category1>
/ items = (1, 2, 3, 4, 5, 6, 7, 8,
1, 2, 3, 4, 5, 6, 7, 8,
1, 2, 3, 4, 5, 6, 7, 8,
1, 2, 3, 4, 5, 6, 7, 8,
1, 2, 3, 4, 5, 6, 7, 8,
1, 2, 3, 4, 5, 6, 7, 8)
/ replace = false
</list>

**8 threat Pictures, untrained, portrait**
<list category2>
/ items = (9, 10, 11, 12, 13, 14, 15, 16,
9, 10, 11, 12, 13, 14, 15, 16,
9, 10, 11, 12, 13, 14, 15, 16,
9, 10, 11, 12, 13, 14, 15, 16,
9, 10, 11, 12, 13, 14, 15, 16,
9, 10, 11, 12, 13, 14, 15, 16)
/ replace = false
</list>

**8 Neutral Pictures, untrained, landscape**
<list category3>
/ items = (17, 18, 19, 20, 21, 22, 23, 24,
17, 18, 19, 20, 21, 22, 23, 24,
17, 18, 19, 20, 21, 22, 23, 24,
17, 18, 19, 20, 21, 22, 23, 24,
17, 18, 19, 20, 21, 22, 23, 24,
17, 18, 19, 20, 21, 22, 23, 24)
</list>

**8 Neutral Pictures, untrained, portrait**
<list category4>
/ items = (25, 26, 27, 28, 29, 30, 31, 32,
25, 26, 27, 28, 29, 30, 31, 32,
25, 26, 27, 28, 29, 30, 31, 32,
25, 26, 27, 28, 29, 30, 31, 32,
25, 26, 27, 28, 29, 30, 31, 32,
25, 26, 27, 28, 29, 30, 31, 32)
/ replace = false
</list>

**12 threat Pictures, trained, landscape**
<list category5>
/ items = (33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44,
33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44,
33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44,
33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44,
33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44,
33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44)
/ replace = false
</list>

**12 threat Pictures, trained, portrait**
<list category6>
/ items = (45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56,
45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56,
45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56,
45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56,
45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56,
45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56)
/ replace = false
</list>

**12 Neutral Pictures, trained, landscape**
<list category7>
/ items = (57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68,
57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68,
57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68,
57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68,
57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68,
57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68)
/ replace = false
</list>

**12 Neutral Pictures, trained, portrait**
<list category8>
/ items = (69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80,
69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80,
69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80,
69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80,
69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80,
69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80)
/ replace = false
</list>

That code is not responsible for image selection. You need to look at the respective <list> elements (as mentioned in my previous response).