Millisecond Forums

You will want to use values and a bit of /ontrialbegin and -end logic:

<values>
/ blonde_x = 0%
/ black_x = 0%
/ red_x = 0%
/ selection = ""
</values>

<picture blonde>
/ items = blondeitems
/ hposition = values.blonde_x
</picture>

<picture black>
/ items = blackitems
/ hposition = values.black_x
</picture>

<picture red>
/ items = reditems
/ hposition = values.red_x
</picture>

<list hpos>
/ items = (30%, 70%)
/ selectionrate = always
/ selectionmode = random
</list>

<item blondeitems>
/1 = "blondegirl.jpg"
/2 = "blonde2.jpg"
/3 = "blonde3.jpg"
/4 = "blonde4.jpg"
/5 = "blonde5.jpg"
</item>

<item blackitems>
/1 = "blackgirl.jpg"
/2 = "black2.jpg"
/3 = "black3.jpg"
/4 = "black4.jpg"
/5 = "black5.jpg"
</item>

<item reditems>
/1 = "red1.jpg"
/2 = "red2.jpg"
/3 = "red3.jpg"
/4 = "red4.jpg"
/5 = "red5.jpg"
</item>



<text focuspoint>
/ items = ("  +  ")
/ fontstyle = ("Arial", 4.17%, false, false, false, false, 5, 1)
</text>

<shape erasefocuspoint>
/ shape = rectangle
/ color = white
/ size = (30%,30%)
/ erase = false
</shape>

<shape erasehochformatsport>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape erasehochformatfrei>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape erasequerformatsport>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape erasequerformatfrei>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape eraseblonde>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape eraseblack>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>

<shape erasered>
/ shape = rectangle
/ color = white
/ size = (100%,100%)
/ erase = false
</shape>



<trial blondeblack>
/ ontrialbegin = [
values.blonde_x = list.hpos.nextvalue;
values.black_x = list.hpos.nextvalue;
values.selection = "";
]
/ ontrialend = [
if ((values.blonde_x == 30% && trial.blondeblack.response == 44) || (values.blonde_x == 70% && trial.blondeblack.response == 50)) {
values.selection = "blonde"
} else if ((values.black_x == 30% && trial.blondeblack.response == 44) || (values.black_x == 70% && trial.blondeblack.response == 50)) {
values.selection = "black"
};
]
/ stimulustimes = [0=focuspoint; 2000=erasefocuspoint; 2500=blonde, black; 4500=eraseblonde, eraseblack]
/ validresponse=("y", "m")
/ beginresponsetime = 2500
/ responsemode = free
/ timeout = 4700
</trial>

<trial blondered>
/ ontrialbegin = [
values.blonde_x = list.hpos.nextvalue;
values.red_x = list.hpos.nextvalue;
values.selection = "";
]
/ ontrialend = [
if ((values.blonde_x == 30% && trial.blondered.response == 44) || (values.blonde_x == 70% && trial.blondered.response == 50)) {
values.selection = "blonde"
} else if ((values.red_x == 30% && trial.blondered.response == 44) || (values.red_x == 70% && trial.blondered.response == 50)) {
values.selection = "red"
};
]
/ stimulustimes = [0=focuspoint; 2000=erasefocuspoint; 2500=blonde, red; 4500=eraseblonde, erasered]
/ validresponse=("y", "m")
/ beginresponsetime = 2500
/ responsemode = free
/ timeout = 4700
</trial>

<trial blackred>
/ ontrialbegin = [
values.black_x = list.hpos.nextvalue;
values.red_x = list.hpos.nextvalue;
values.selection = "";
]
/ ontrialend = [
if ((values.black_x == 30% && trial.blackred.response == 44) || (values.black_x == 70% && trial.blackred.response == 50)) {
values.selection = "black"
} else if ((values.red_x == 30% && trial.blackred.response == 44) || (values.red_x == 70% && trial.blackred.response == 50)) {
values.selection = "red"
};
]
/ stimulustimes = [0=focuspoint; 2000=erasefocuspoint; 2500=black, red; 4500=eraseblack, erasered]
/ validresponse=("y", "m")
/ beginresponsetime = 2500
/ responsemode = free
/ timeout = 4700
</trial>


<block selection>
/ trials = [1-125 = noreplacenorepeat (blondeblack, blackred, blondered)]
</block>


<page intro>
^^^Sport oder Nicht
^^Danke dass du an dieser Studie teilnimmst.
^^Bitte schalte dein Mobiltelefon aus und stelle sicher, dass du dich in einer ruhigen Atmosphäre befindest.
</page>


<page task>
^^Einleitung:
Du wirst in jedem Durchgang immer zwei Bilder von unterschiedlichen AKtivitäten sehen. Deine Aufgabe besteht darin ganz natürlich und intuitiv ohne lange darüber nachzudenken, dich für eine der beiden per Knopfdruck zu entscheiden.
^^Dabei steht "y" für "links" und "m" für "rechts".
</page>


<page end>
Das Expreiment ist nun beendet.
^^Danke für deine Teilnahme.
</page>


<instruct>
/ nextkey = (" ")
/ lastlabel = ("Drücke die Leertaste um fortzufahren")
/ nextlabel = ("Drücke die Leertaste um fortzufahren")
/ fontstyle = ("Arial", 16pt)
</instruct>

<expt>
/ preinstructions = (intro, task)
/ postinstructions = (end)
/ blocks = [1=selection]
</expt>


<defaults>
/ fontstyle = ("Courier New", 16pt)
/ posttrialpause = 500
</defaults>

<data>
/ columns = (date time subject group blocknum blockcode trialnum trialcode stimulusitem stimulusitem stimulusitem stimulusitem
response latency correct values.selection)
/ separatefiles = true
</data>

Hey thank you so much. How fast this answer came. Amazing. I will try it.

Yes it functions perfectly. Best wishes to you.