Millisecond Forums

The scripts already have a parameter (parameters.showsummaryfeedback) that determines whether the feedback is shown. All you need to do is add a <trial> to the scripts that sets the parameter to either false or true depending on the participant's response.

<block summary_choice>
/ trials = [1=summarychoicetrial]
</block>

<trial summarychoicetrial>
/ ontrialend = [
if (trial.summarychoicetrial.response == 18) {
parameters.showsummaryfeedback = true;
} else if (trial.summarychoicetrial.response == 23) {
parameters.showsummaryfeedback = false;
};
]
/ stimulusframes = [1=summarychoice]
/ validresponse = ("E", "I")
</trial>

<text summarychoice>
/ items = ("Do you want to see your results? Press 'E' for yes, press 'I' for no.")
</text>

Then run the above block and trial before the summary block:

<expt>
/ preinstructions = (iatintro)
/subjects = (1 of 2)
/groupassignment = groupnumber
/ blocks = [
1=targetcompatiblepractice;
2=attributepractice;
3=compatibletest1;
4=compatibletestinstructions;
5=compatibletest2;
6=targetincompatiblepractice;
7=incompatibletest1;
8=incompatibletestinstructions;
9=incompatibletest2;
10=summary_choice;
11=summary;
]
/onexptend = [values.completed = 1]
</expt>

<expt>
/ preinstructions = (iatintro)
/subjects = (2 of 2)
/groupassignment = groupnumber
/ blocks = [
1=targetincompatiblepractice;
2=attributepractice;
3=incompatibletest1;
4=incompatibletestinstructions;
5=incompatibletest2;
6=targetcompatiblepractice;
7=compatibletest1;
8=compatibletestinstructions;
9=compatibletest2;
10=summary_choice;
11=summary;
]
/onexptend = [values.completed = 1]
</expt>

That is absolutely fantastic, it worked perfectly, thank you so much for the help, that has really helped me to better understand how experiments are put together in Inquisit even beyond the narrow problem I described. Thanks again for taking the time to give such a detailed response.