+xHello!
Can anyone help me with programming a matrix table? I want it to look something like this:
Thank you so much in advance!
No easy way to do this. You'll need to define <radiobuttons> and <caption> elements as needed and then position them on a surveypage one by one.
<defaults>
/ fontstyle = ("Arial", 3%)
/ canvasaspectratio = (16,9)
</defaults>
<surveypage mypage>
/ questions = [1= h1, h2, h3, h4, h5 disgustcaption, admirationcaption; 2=disgust, admiration]
/ showpagenumbers = false
/ showquestionnumbers = false
</surveypage>
<caption h1>
/ caption = "Not at all"
/ position = (31%, 10%)
</caption>
<caption h2>
/ caption = "A little"
/ position = (44%, 10%)
</caption>
<caption h3>
/ caption = "Somewhat"
/ position = (53%, 10%)
</caption>
<caption h4>
/ caption = "A lot"
/ position = (67%, 10%)
</caption>
<caption h5>
/ caption = "Extremely"
/ position = (76%, 10%)
</caption>
<caption disgustcaption>
/ caption = "Disgust"
/ position = (10%, 15%)
</caption>
<radiobuttons disgust>
/ options = (" ", " ", " ", " ", " ")
/ optionvalues = ("1", "2", "3", "4", "5")
/ orientation = horizontalequal
/ position = (30%, 15%)
</radiobuttons>
<caption admirationcaption>
/ caption = "Admiration"
/ position = (10%, 20%)
</caption>
<radiobuttons admiration>
/ options = (" ", " ", " ", " ", " ")
/ optionvalues = ("1", "2", "3", "4", "5")
/ orientation = horizontalequal
/ position = (30%, 20%)
</radiobuttons>