|
Group: Forum Members
Posts: 47,
Visits: 153
|
I have a script that worked in v5 when I tried to run the code in v6 it no longer works.
Basically I define a set of sliders each with a different question. I then use a survey page to pick a slider, and a survey to present the survey pages.
It used to work ok with a sequence of different questions appearing.
Now is presents the same single question over and over. The survey page seems stuck on the first selection is there a way to force a new selection every time a page is displayed?
Here is the critical part of the code:
<surveypage surveypagename>
/ questions=[1 =noreplace(q1,q2,q3,q4,q5,q6,q7,q8,q9,q10,q11,q12,q13,q14,q15,q16,q17,q18,q19,q20,q21,q22,q23,q24,q25,q26,q27,q28,q29,q30,q31,q32,q33,q34,q35,q36,q37,q38,q39,q40,q41,q42,q43,q44,q45,q46,q47,q48,q49,q50)]
/ showquestionnumbers = false
/ showpagenumbers = false
/ caption = "How much do you agree with this statement?"
/ nextbuttonposition = (50, 50)
</surveypage>
<survey surveyname>
/ pages=[1-50=surveypagename]
/ showbackbutton = false
</survey>
|
|
Group: Administrators
Posts: 12K,
Visits: 98K
|
+xI have a script that worked in v5 when I tried to run the code in v6 it no longer works. Basically I define a set of sliders each with a different question. I then use a survey page to pick a slider, and a survey to present the survey pages. It used to work ok with a sequence of different questions appearing. Now is presents the same single question over and over. The survey page seems stuck on the first selection is there a way to force a new selection every time a page is displayed? Here is the critical part of the code: <surveypage surveypagename> / questions=[1 =noreplace(q1,q2,q3,q4,q5,q6,q7,q8,q9,q10,q11,q12,q13,q14,q15,q16,q17,q18,q19,q20,q21,q22,q23,q24,q25,q26,q27,q28,q29,q30,q31,q32,q33,q34,q35,q36,q37,q38,q39,q40,q41,q42,q43,q44,q45,q46,q47,q48,q49,q50)] / showquestionnumbers = false / showpagenumbers = false / caption = "How much do you agree with this statement?" / nextbuttonposition = (50, 50) </surveypage> <survey surveyname> / pages=[1-50=surveypagename] / showbackbutton = false </survey> That won't work under Inquisit 6; this behavior in Inquisit 5 was always problematic and caused problems in many situations (e.g. when branching or skipping was involded, pages couldn't keep their previous state when navigating back). If you want to do something similar in Inquisit 6, you can flip things around. That is: Have a single <slider> (assuming the reponse range is identical for each question), have a page for each question, sample the pages in random order. <survey mysurvey>
/ pages = [1-3 = noreplace(q1,q2,q3)]
/ nextbuttonposition = (50%, 50%)
/ showpagenumbers = false
/ showquestionnumbers = false
/ showbackbutton = false
</survey>
<surveypage q1>
/ caption = "How much do you agree with this statement?"
/ subcaption = "Q1"
/ questions = [1=rating]
</surveypage>
<surveypage q2>
/ caption = "How much do you agree with this statement?"
/ subcaption = "Q2"
/ questions = [1=rating]
</surveypage>
<surveypage q3>
/ caption = "How much do you agree with this statement?"
/ subcaption = "Q3"
/ questions = [1=rating]
</surveypage>
<slider rating>
/ labels = ("Disagree", "Agree")
/ range = (0,10)
</slider> Alternatively, use <slidertrial> and a <block> instead of <survey>. https://www.millisecond.com/support/docs/current/html/language/elements/slidertrial.htm<block myblock>
/ trials = [1-3 = myslidertrial]
</block>
<slidertrial myslidertrial>
/ stimulusframes = [1=question]
/ labels = ("Disagree", "Agree")
/ range = (0,10)
/ size = (50%, 15%)
/ position = (50%, 70%)
</slidertrial>
<text question>
/ items = questions
/ select = noreplace
</text>
<item questions>
/ 1 = "Q1"
/ 2 = "Q2"
/ 3 = "Q3"
</item>
|