|
Group: Forum Members
Posts: 24,
Visits: 126
|
Hi
I have two sets of stimuli, say A and B. A has six items and B has five items. I want to pair each item from list A with an Itea from List B. So that:
A. In the experiment I have all 30 possible pairs
B. Each pair appears just once
C. The order of pair appearance is random
How can I achieve that?
Thanks much
Shlomo
|
|
Group: Administrators
Posts: 13K,
Visits: 105K
|
+xHi I have two sets of stimuli, say A and B. A has six items and B has five items. I want to pair each item from list A with an Itea from List B. So that: A. In the experiment I have all 30 possible pairs B. Each pair appears just once C. The order of pair appearance is random How can I achieve that? Thanks much Shlomo Pair the item numbers using two linked <list>s, use those lists for item / pair selection. No different than https://www.millisecond.com/support/docs/current/html/howto/howtopairs.htm really.
|
|
Group: Administrators
Posts: 13K,
Visits: 105K
|
+x+xHi I have two sets of stimuli, say A and B. A has six items and B has five items. I want to pair each item from list A with an Itea from List B. So that: A. In the experiment I have all 30 possible pairs B. Each pair appears just once C. The order of pair appearance is random How can I achieve that? Thanks much Shlomo Pair the item numbers using two linked <list>s, use those lists for item / pair selection. No different than https://www.millisecond.com/support/docs/current/html/howto/howtopairs.htm really. <item aitems>
/ 1 = "A01"
/ 2 = "A02"
/ 3 = "A03"
/ 4 = "A04"
/ 5 = "A05"
/ 6 = "A06"
</item>
<item bitems>
/ 1 = "B01"
/ 2 = "B02"
/ 3 = "B03"
/ 4 = "B04"
/ 5 = "B05"
</item>
<list a>
/ items = (
1,2,3,4,5,6,
1,2,3,4,5,6,
1,2,3,4,5,6,
1,2,3,4,5,6,
1,2,3,4,5,6
)
</list>
<list b>
/ items = (
1,1,1,1,1,1,
2,2,2,2,2,2,
3,3,3,3,3,3,
4,4,4,4,4,4,
5,5,5,5,5,5
)
/ selectionmode = list.a.currentindex
</list>
<text astim>
/ items = aitems
/ select = list.a.nextvalue
/ position = (30%, 50%)
</text>
<text bstim>
/ items = bitems
/ select = list.b.nextvalue
/ position = (70%, 50%)
</text>
<trial abtrial>
/ stimulusframes = [1=text.astim, text.bstim]
/ validresponse = (57)
</trial>
<block abblock>
/ trials = [1-30 = trial.abtrial]
</block>
<data>
/ columns = (
date time subject group session blocknum blockcode trialnum trialcode response latency correct
stimulusitem stimulusitem)
</data>
|