Millisecond Forums

<expt example>
/ onexptbegin = [
    var i = 0;
    // pick 3 statement item numbers for encoding in block 1
    while(i < 3) {
        list.old_statements.appenditem(list.all.nextindex);
        // these item numbers will be new question items in block 2
        list.new_questions.appenditem(list.all.currentindex);
        i += 1;
    };
    // pick the remaining 3 item numbers for questions in encoding block 1
    i = 0;
    while(i < 3) {
        list.old_questions.appenditem(list.all.nextindex);
        // these item numbers will be new statements items in block 2
        list.new_statements.appenditem(list.all.currentindex);
        i += 1;
    };
]
/ blocks = [1=block.block1; 2=block.block2]
</expt>

<values>
/ itemnumber = 0
</values>

// old statements and questions
<list old_statements>
</list>
<list old_questions>
</list>

// new statements and questions
<list new_statements>
</list>
<list new_questions>
</list>

<list all>
/ poolsize = 6
/ selectionrate = always
</list>

<item statements>
/1 = "A"
/2 = "B"
/3 = "C"
/4 = "D"
/5 = "E"
/6 = "F"
</item>

<item questions>
/1 = "A?"
/2 = "B?"
/3 = "C?"
/4 = "D?"
/5 = "E?"
/6 = "F?"
</item>

<text statement>
/ items = item.statements
/ select = values.itemnumber
</text>

<text question>
/ items = item.questions
/ select = values.itemnumber
</text>

<trial encode_statement>
/ ontrialbegin = [
    values.itemnumber = list.old_statements.nextvalue;
]
/ stimulusframes = [1=text.statement]
/ validresponse = (57)
</trial>

<trial encode_question>
/ ontrialbegin = [
    values.itemnumber = list.old_questions.nextvalue;
]
/ stimulusframes = [1=text.question]
/ validresponse = (57)
</trial>

<block block1>
/ trials = [1-6 = noreplace(trial.encode_statement, trial.encode_question)]
</block>

<trial old_statement>
/ ontrialbegin = [
    values.itemnumber = list.old_statements.nextvalue;
]
/ stimulusframes = [1=text.statement]
/ validresponse = (57)
</trial>

<trial old_question>
/ ontrialbegin = [
    values.itemnumber = list.old_questions.nextvalue;
]
/ stimulusframes = [1=text.question]
/ validresponse = (57)
</trial>

<trial new_statement>
/ ontrialbegin = [
    values.itemnumber = list.new_statements.nextvalue;
]
/ stimulusframes = [1=text.statement]
/ validresponse = (57)
</trial>

<trial new_question>
/ ontrialbegin = [
    values.itemnumber = list.new_questions.nextvalue;
]
/ stimulusframes = [1=text.question]
/ validresponse = (57)
</trial>

<block block2>
/ trials = [1-12 = noreplace(trial.old_statement, trial.old_question, trial.new_statement, trial.new_question)]
</block>

<data>
/ columns = (date time subject group session blocknum blockcode trialnum trialcode stimulusitem response latency correct)
</data>