Hello,
We used the picture IAT script as well as the standard IAT from Inquisit 4 for a research project and learned afterwards that the Picture IAT script does not generate expressions. d score (see bolded portion at the end of the picture IAT script that I pasted below, although the standard IAT script does).
While I would prefer that Millisecond provides that, this was not considered a big problem for us as there are guidelines to compute it (e.g., Greenwald et al., 2003) for use to use this opportunity to learn something. Additionally, because our standard IAT has already generated expressions d, we first used one subject's data from the Standard IAT dataset to practice to see if we could get an identical result from what it generated from the script (block 9, trinum 40). In doing the practice run, we followed the 12-step protocol by Greenwald et al., 2003.
We had thought it would be fairly easy: we follow the steps, get the number that is identical to what the script has generated, then move on to compute the d score for the picture IAT. Well that was a few days ago, so far none of us has been able to get a score that is even close to what was generated by the standard IAT script. We suspect that
1. The standard IAT scoring algorithm is not identical to Greenwald's 12-step protocol. If that is the case, we wonder what changes have been made and why?
2. Also in the Greenwald protocol, it talked about Block 3 and Block 6 as practice blocks, in Inquisit 4, they seem to have been changed to compatibletest1 and incompatibletest1 but we are not sure if that is the case.
3. Using the block mean of correct response plus 600 to impute the incorrect block response might be problematic. In the case of our pratice subject, the latency for the correct responses ranged from 600 to 800 ms (M = about 600) for one block. If we add 600 to it, that seems way off. Results differed fairly drastically after the imputation too.
4. Can anyone give us a up-to-date suggestion of what/whom we should follow to compute the d score?
Thanks
Picture IAT script from Inquisit4 below:
***********************************************************************
This sample picture IAT can be easily adapted to different target categories
and attributes. To change the categories, you need only change the
stimulus items and labels immediately below this line.
***********************************************************************
<item attributeAlabel>
/1 = "Good"
</item>
<item attributeA>
/1 = "Marvelous"
/2 = "Superb"
/3 = "Pleasure"
/4 = "Beautiful"
/5 = "Joyful"
/6 = "Glorious"
/7 = "Lovely"
/8 = "Wonderful"
</item>
<item attributeBlabel>
/1 = "Bad"
</item>
<item attributeB>
/1 = "Tragic"
/2 = "Horrible"
/3 = "Agony"
/4 = "Painful"
/5 = "Terrible"
/6 = "Awful"
/7 = "Humiliate"
/8 = "Nasty"
</item>
<item targetAlabel>
/1 = "Flowers"
</item>
<item targetA>
/1 = "flower1.jpg"
/2 = "flower2.jpg"
/3 = "flower3.jpg"
/4 = "flower4.jpg"
/5 = "flower5.jpg"
/6 = "flower6.jpg"
/7 = "flower7.jpg"
/8 = "flower8.jpg"
</item>
<item targetBlabel>
/1 = "Insects"
</item>
<item targetB>
/1 = "insect1.jpg"
/2 = "insect2.jpg"
/3 = "insect3.jpg"
/4 = "insect4.jpg"
/5 = "insect5.jpg"
/6 = "insect6.jpg"
/7 = "insect7.jpg"
/8 = "insect8.jpg"
</item>
***********************************************************************
To change the categories, you need only change the stimulus items and
labels immediately above this line. All commands below relate to the
IAT procedure, and need only be changed if you wish to modify the
generic IAT procedure.
***********************************************************************
***********************************************************************
Performance summary
***********************************************************************
<instruct>
/ nextlabel = "Continue"
/ lastlabel = "Continue"
/ nextkey = (" ")
/ prevkey = (0)
/ inputdevice = mouse
/ windowsize = (90%, 90%)
/ screencolor = (0,0,0)
/ fontstyle = ("Arial", 3%)
/ txcolor = (255, 255, 255)
</instruct>
<page summary>
^Below is a summary of your average response time for two different configurations.
^^Configuration 1: <% item.targetAlabel.1 %> with <% item.attributeAlabel.1 %>, <% item.targetBlabel.1 %> with <% item.attributeBlabel.1 %>
^ <%block.compatibletest.meanlatency%> milliseconds
^^Configuration 2: <% item.targetAlabel.1 %> with <% item.attributeBlabel.1 %>, <% item.targetBlabel.1 %> with <% item.attributeAlabel.1 %>
^ <%block.incompatibletest.meanlatency%> milliseconds
^^Did you respond much more quickly on one of the configurations than the other? If so, that configuration may be more consistent with your attitudes about these categories.
^^Thank you for your participation. Please press 'Continue' to end the test.
</page>
***********************************************************************
Task instruction stimuli
***********************************************************************
<counter instructions>
/ resetinterval = 20
/ select = sequence(1, 2, 3, 4, 5, 6, 7)
</counter>
<trial instructions>
/ stimulustimes = [1=instructions, spacebar]
/ correctresponse = (" ")
/ errormessage = false
/ recorddata = false
</trial>
<text instructions>
/ items = instructions
/ hjustify = left
/ size = (90%, 60%)
/ position = (50%, 85%)
/ valign = bottom
/ select = instructions
/ fontstyle = ("Arial", 3.5%)
</text>
<item instructions>
/ 1 = "Put your middle or index fingers on the E and I keys of your keyboard. Pictures or words representing the categories at the top will appear one-by-one in the middle of the screen. When the item belongs to a category on the left, press the E key; when the item belongs to a category on the right, press the I key. Items belong to only one category. If you make an error, an X will appear - fix the error by hitting the other key.
This is a timed sorting task. GO AS FAST AS YOU CAN while making as few mistakes as possible. Going too slow or making too many errors will result in an uninterpretable score. This task will take about 5 minutes to complete."
/ 2 = "See above, the categories have changed. the items for sorting have changed as well. The rules, however, are the same.
When the item belongs to a category on the left, press the E key; when the item belongs to a category on the right, press the I key. Items belong to only one category. An X appears after an error - fix the error by hitting the other key. GO AS FAST AS YOU CAN."
/ 3 = "See above, the four categories you saw separately now appear together. Remember, each item belongs to only one group. For example, if the categories flower and good appeared on the separate sides above - pictures or words meaning flower would go in the flower category, not the good category.
The green and white labels and items may help to identify the appropriate category. Use the E and I keys to categorize items into four groups left and right, and correct errors by hitting the other key."
/ 4 = "Sort the same four categories again. Remember to go as fast as you can while making as few mistakes as possible.
The green and white labels and items may help to identify the appropriate category. Use the E and I keys to categorize items into the four groups left and right, and correct errors by hitting the other key."
/ 5 = "Notice above, there are only two categories and they have switched positions. The concept that was previously on the left is now on the right, and the concept that was on the right is now on the left. Practice this new configuration.
Use the E and I keys to catgorize items left and right, and correct errors by hitting the other key."
/ 6 = "See above, the four categories now appear together in a new configuration. Remember, each item belongs to only one group.
The green and white labels and items may help to identify the appropriate category. Use the E and I keys to categorize items into the four groups left and right, and correct errors by hitting the other key."
/ 7 = "Sort the same four categories again. Remember to go as fast as you can while making as few mistakes as possible.
The green and white labels and items may help to identify the appropriate category. Use the E and I keys to categorize items into the four groups left and right, and correct errors by hitting the other key."
</item>
<text spacebar>
/ items = ("Press the SPACE BAR to begin.")
/ position = (50%, 95%)
/ valign = bottom
/ fontstyle = ("Arial", 3.5%)
</text>
<text attributeA>
/ items = attributeA
/ txcolor = (0, 255, 0)
</text>
<text attributeB>
/ items = attributeB
/ txcolor = (0, 255, 0)
</text>
<picture targetB>
/ items = targetB
/ size = (20%, 20%)
</picture>
<picture targetA>
/ items = targetA
/ size = (20%, 20%)
</picture>
<text error>
/ position = (50%, 75%)
/ items = ("X")
/ color = (255, 0, 0)
/ fontstyle = ("Arial", 10%, true)
</text>
<text attributeAleft>
/ items = attributeAlabel
/ valign = top
/ halign = left
/ position = (5%, 5%)
/ txcolor = (0, 255, 0)
</text>
<text attributeBright>
/ items = attributeBlabel
/ valign = top
/ halign = right
/ position = (95%, 5%)
/ txcolor = (0, 255, 0)
</text>
<text attributeAleftmixed>
/ items = attributeAlabel
/ valign = top
/ halign = left
/ position = (5%, 19%)
/ txcolor = (0, 255, 0)
</text>
<text attributeBrightmixed>
/ items = attributeBlabel
/ valign = top
/ halign = right
/ position = (95%, 19%)
/ txcolor = (0, 255, 0)
</text>
<text targetBleft>
/ items = targetBlabel
/ valign = top
/ halign = left
/ position = (5%, 5%)
</text>
<text targetBright>
/ items = targetBlabel
/ valign = top
/ halign = right
/ position = (95%, 5%)
</text>
<text targetAleft>
/ items = targetAlabel
/ valign = top
/ halign = left
/ position = (5%, 5%)
</text>
<text targetAright>
/ items = targetAlabel
/ valign = top
/ halign = right
/ position = (95%, 5%)
</text>
<text orleft>
/ items = ("or")
/ valign = top
/ halign = left
/ position = (5%, 12%)
</text>
<text orright>
/ items = ("or")
/ valign = top
/ halign = right
/ position = (95%, 12%)
</text>
***********************************************************************
Trials
***********************************************************************
<trial attributeA>
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = attributeA]
/ posttrialpause = 250
</trial>
<trial attributeB>
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = attributeB]
/ posttrialpause = 250
</trial>
<trial targetBleft>
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = targetB]
/ posttrialpause = 250
</trial>
<trial targetBright>
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = targetB]
/ posttrialpause = 250
</trial>
<trial targetAleft>
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = targetA]
/ posttrialpause = 250
</trial>
<trial targetAright>
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = targetA]
/ posttrialpause = 250
</trial>
***********************************************************************
Blocks
***********************************************************************
<block attributepractice>
/ bgstim = (attributeAleft, attributeBright)
/ trials = [1=instructions;2-21 = noreplace(attributeA, attributeB)]
/ errormessage = true(error,200)
/ responsemode = correct
/ recorddata = false
</block>
<block targetcompatiblepractice>
/ bgstim = (targetAleft, targetBright)
/ trials = [1=instructions;2-21 = noreplace(targetAleft, targetBright)]
/ errormessage = true(error,200)
/ responsemode = correct
/ recorddata = false
</block>
<block targetincompatiblepractice>
/ bgstim = (targetAright, targetBleft)
/ trials = [1=instructions;2-21 = noreplace(targetAright, targetBleft)]
/ errormessage = true(error,200)
/ responsemode = correct
/ recorddata = false
</block>
<block targetcompatiblepracticeswitch>
/ bgstim = (targetAleft, targetBright)
/ trials = [1=instructions;2-41 = noreplace(targetAleft, targetBright)]
/ errormessage = true(error,200)
/ responsemode = correct
/ recorddata = false
</block>
<block targetincompatiblepracticeswitch>
/ bgstim = (targetAright, targetBleft)
/ trials = [1=instructions;2-41 = noreplace(targetAright, targetBleft)]
/ errormessage = true(error,200)
/ responsemode = correct
/ recorddata = false
</block>
<block compatiblepractice>
/ bgstim = (targetAleft, orleft, attributeAleftmixed, targetBright, orright, attributeBrightmixed)
/ trials = [1=instructions;
3,5,7,9,11,13,15,17,19,21= noreplace(targetAleft, targetBright);
2,4,6,8,10,12,14,16,18,20 = noreplace(attributeA, attributeB)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>
<block incompatiblepractice>
/ bgstim = (targetBleft, orleft, attributeAleftmixed, targetAright, orright, attributeBrightmixed)
/ trials = [1=instructions;
3,5,7,9,11,13,15,17,19,21 = noreplace(targetBleft, targetAright);
2,4,6,8,10,12,14,16,18,20 = noreplace(attributeA, attributeB)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>
<block compatibletestinstructions>
/ bgstim = (targetAleft, orleft, attributeAleftmixed, targetBright, orright, attributeBrightmixed)
/ trials = [1=instructions]
/ recorddata = false
</block>
<block compatibletest>
/ bgstim = (targetAleft, orleft, attributeAleftmixed, targetBright, orright, attributeBrightmixed)
/ trials = [
2,4,6,8,10,12,14,16,18,20,22,24,26,28,30,32,34,36,38,40 = noreplace(targetAleft, targetBright);
1,3,5,7,9,11,13,15,17,19,21,23,25,27,29,31,33,35,37,39 = noreplace(attributeA, attributeB)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>
<block incompatibletestinstructions>
/ bgstim = (targetBleft, orleft, attributeAleftmixed, targetAright, orright, attributeBrightmixed)
/ trials = [1=instructions]
/ recorddata = false
</block>
<block incompatibletest>
/ bgstim = (targetBleft, orleft, attributeAleftmixed, targetAright, orright, attributeBrightmixed)
/ trials = [
2,4,6,8,10,12,14,16,18,20,22,24,26,28,30,32,34,36,38,40 = noreplace(targetBleft, targetAright);
1,3,5,7,9,11,13,15,17,19,21,23,25,27,29,31,33,35,37,39 = noreplace(attributeA, attributeB)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>
***********************************************************************
Experiment
***********************************************************************
<defaults>
/ screencolor = (0,0,0)
/ txbgcolor = (0,0,0)
/ txcolor = (255, 255, 255)
/ fontstyle = ("Arial", 5%)
</defaults>
<expt>
/ blocks = [1=attributepractice; 2=block2; 3=block3; 4=block4; 5=block5; 6=block6; 7=block7; 8=block8; 9=block9]
/ postinstructions = (summary)
</expt>
<variables>
/ group = (1 of 2) (block2=targetcompatiblepractice; block3=compatiblepractice; block4=compatibletestinstructions; block5=compatibletest; block6=targetincompatiblepractice; block7=incompatiblepractice; block8=incompatibletestinstructions; block9=incompatibletest)
/ group = (2 of 2) (block2=targetincompatiblepractice; block3=incompatiblepractice; block4=incompatibletestinstructions; block5=incompatibletest; block6=targetcompatiblepractice; block7=compatiblepractice; block8=compatibletestinstructions; block9=compatibletest)
</variables>
<data>
/ columns = [date time subject blockcode blocknum trialcode trialnum response correct latency stimulusnumber stimulusitem stimulusnumber stimulusitem]
</data>