Millisecond Forums

Inquisit's *default* is to erase stimuli (i.e. overwrite them; cf. the /erase attribute) at the end of a trial, which normally is when a response has occurred. This, however, is not what you want here. You want to keep stimuli on screen for a fixed period, even if a response has already occurred. There are a couple of different ways to do this, and I've outlined one in the example, specifically using the trial's /responseinterrupt attribute to keep the stimulus presentation sequence going after response and -- here -- overwrite the stimulus after the desired amount of time.

Hope this clarifies.

Some packages allow you to write a black screen that is just the default screen. If I'm understanding correctly, here the default is just for initializing. Or can it be used to overwrite the presented stim rather than having to create an additional blank stimulus? Presumably the erase function uses the defaults? It's not a huge burden obviously to create the blank stim but I want to be clear on whether this is necessary.

> rather than remove the stimulus at a specified time, this method displays a blank image over that stimulus.

Yes, which is the exact same thing as removing a stimulus. For something on the screen to "disappear" it needs to be painted over with something else (here a blank shape covering the entire screen). That is *always* the case in some form or another. Objects drawn to a screen are unlike physical objects which you can, say, place on a desk and later remove from said desk.

Also see https://www.millisecond.com/support/docs/v4/html/howto/howtoerase.htm

> Relatedly, does this addition of images (rather than removal) increase the load on the system

There is no additional image and hence no additional load.

Ok, thanks. Just to be clear, rather than remove the stimulus at a specified time, this method displays a blank image over that stimulus. Should I assume then that there is no way to simply remove the stimulus at a specified point within the trial such that the default reappears until the next trial? Relatedly, does this addition of images (rather than removal) increase the load on the system by increasing the images in memory or should this have no effect?

You can do something along the lines of

<block myblock>
/ trials = [1-8 = noreplace(vowel, consonant)]
</block>

<trial vowel>
/ stimulustimes = [0=vowel; 1500=blank; 2000=blank]
/ validresponse = ("v", "c")
/ correctresponse = ("v")
/ beginresponsetime = 0
/ responseinterrupt = frames
/ trialduration = 2000
</trial>

<trial consonant>
/ stimulustimes = [0=consonant; 1500=blank; 2000=blank]
/ validresponse = ("v", "c")
/ correctresponse = ("c")
/ beginresponsetime = 0
/ responseinterrupt = frames
/ trialduration = 2000
</trial>

<text vowel>
/ items = vowels
/ erase = false
</text>

<item vowels>
/ 1 = "A"
/ 2 = "E"
/ 3 = "I"
/ 4 = "O"
</item>

<text consonant>
/ items = consonants
/ erase = false
</text>

<item consonants>
/ 1 = "B"
/ 2 = "F"
/ 3 = "J"
/ 4 = "P"
</item>

<shape blank>
/ color = white
/ shape = rectangle
/ size = (100%, 100%)
/ erase = false
</shape>

(works the same with <picture> instead of <text> stimuli).