+x+xHi. I'd like to know how to make a sound box with slider in my survey page.
Please help me.
I use Inquisit 6 and Web version.
My ideal is;
sound box (The subject can click a start button.)
slider (For example, 1-10 unlike-like; Likert scale)
*My code for now is;
<surveypage section1>
/caption ="CAPTION"
/questions = [1 = Q11, Q12;]
</surveypage>
<slider Q11>
/ caption="How do you like it?"
/ labels=("0%","25%","50%","75%", "100%",)
/ range = (0, 100)
/ increment = 1
/ showticks = true
/ required = true
</slider>
<slider Q12>
/ caption="How do you recommend this to your friend?"
/ labels=("0%","25%","50%","75%", "100%",)
/ increment = 1
/ showticks = true
/ required = true
</slider>
What do you understand a "sound box" to be? Please take the time and explain in detail what exactly you want to do. Otherwise I cannot help you.
Guessing here, but what you would typically do is something like this:
<block example>
/ trials = [1-4 = start]
</block>
<values>
/ sound = ""
</values>
<trial start>
/ stimulusframes = [1=clearscreen, startbutton]
/ validresponse = (startbutton)
/ inputdevice = mouse
/ recorddata = false
/ branch = [
return trial.playsound;
]
</trial>
<text startbutton>
/ items = ("PLAY SOUND")
/ position = (50%, 50%)
/ size = (20%, 10%)
/ txcolor = white
/ txbgcolor = black
/ hjustify = center
/ vjustify = center
/ erase = false
</text>
<trial playsound>
/ ontrialend = [
values.sound = video.mysound.currentitem;
]
/ stimulusframes = [1=clearscreen, mysound]
/ validresponse = (0)
/ trialduration = 10
/ recorddata = false
/ branch = [
return surveypage.rating;
]
</trial>
<video mysound>
/ items = sounditems
/ playthrough = true
</video>
<item sounditems>
/ 1 = "sound_a.mp3"
/ 1 = "sound_b.mp3"
/ 1 = "sound_c.mp3"
/ 1 = "sound_d.mp3"
</item>
<surveypage rating>
/caption ="Please rate the sound you just heard"
/questions = [1=q1; 2=q2]
/ showpagenumbers = false
/ showquestionnumbers = false
</surveypage>
<slider q1>
/ caption="How do you like it?"
/ labels=("0%","25%","50%","75%", "100%",)
/ range = (0, 100)
/ increment = 1
/ showticks = true
/ required = true
</slider>
<slider q2>
/ caption="How do you recommend this to your friend?"
/ labels=("0%","25%","50%","75%", "100%",)
/ increment = 1
/ showticks = true
/ required = true
</slider>
<data>
/ columns = (date time build subject group session blocknum blockcode trialnum trialcode values.sound response latency)
/ separatefiles = true
</data>