Millisecond Forums

The <sound> element has a /volume attribute which should be able to handle variables, e.g.

<sound mysound>
/ items = ("mysound.wav")
/ volume = values.myvolume
</sound>

See the documentation for details. You can't make sounds louder, so set the systems volume high. But you could allow subjects to make sounds less loud.

Split your video in 25s and 5s segments respectively and select them sequentially. There's no way to make Inquisit resume a video from a previous position.

Nope, no way to control the monitor state from within Inquisit. Black picture or shape is your best option.

~Dave

Thanks for the answers!

Splitting the answers isn't really an option because if you have a dichotomous choice with 20 opportunities to select either response, there are 2^20 = 1048576 possible orders.

That would be quite a long script.. Hmm any other thoughts on this?

Thx!

Well, it's not like you'd have to hardcode any of these orders, so that figure is totally irrelevant. After all, the sequence is determined by the subject's choices. All you need is something along these lines:

<values>
/ longvid = 0
/ shortvid = 0
</values>

<block myblock>
/ trials = [1=choice]
</block>

<trial choice>
/ stimulusframes = [1=selectlong, selectshort]
/ inputdevice = mouse
/ validresponse = (selectlong, selectshort)
/ branch = [if(trial.choice.response=="selectlong")trial.playlong else trial.playshort]
</trial>

<text selectlong>
/ items = ("Play long video")
/ position = (40%, 50%)
</text>

<text selectshort>
/ items = ("Play short video")
/ position = (60%, 50%)
</text>

<trial playlong>
/ ontrialbegin = [values.longvid=values.longvid+1]
/ stimulusframes = [1=longvideo]
/ validresponse = (anyresponse)
/ branch = [trial.choice]
</trial>

<trial playshort>
/ ontrialbegin = [values.shortvid=values.shortvid+1]
/ stimulusframes = [1=shortvideo]
/ validresponse = (anyresponse)
/ branch = [trial.choice]
</trial>

<text longvideo>
/ items = longvideosegments
/ select = values.longvid
</text>

<text shortvideo>
/ items = shortvideosegments
/ select = values.shortvid
</text>

<item longvideosegments>
/ 1 = "long video segment 1"
/ 2 = "long video segment 2"
/ 3 = "long video segment 3"
</item>

<item shortvideosegments>
/ 1 = "short video segment 1"
/ 2 = "short video segment 2"
/ 3 = "short video segment 3"
</item>

Regards

~Dave

Still wrapping my brains around this one,

I like your solution. However, as it is possible for each last trial to have been the short video of 5 seconds, with 20 choice moments there are 20*5=100 possible starting points for the short vid trial, and 100 possible starting points for the long vid trial.

And i don't think Inquist could handle loading 200 video segments.

Best,

Tom!

And this is important, because...?

Given enough RAM, why not?

In regards to using the /volume attribute, the values.myvolume element can store and update values, but how can a participant use the mouse to select a preferred volume level? Is there a way to insert a slider on the screen where participants can adjust the slide-bar to reflect their most comfortable volume level as a sound clip is being played at the same time?

I understand that the sound level cannot be made any louder, but I do not know how to program a script that allows the flexibility to adjust volume. I am intending to first let the participant find a comfortable volume, and then play an 8-minute meditation audio file. It would not be optimal if the volume was too loud or too soft while the audio file was playing. 

Thanks in advance!

I don't think what you want is possible to do in Inquisit. Why not let your subjects find a comfortable volume first (i.e. set the standard Windows system volume) and only then start the experiment?